Working template (RmlUi 6.2)

Needs:
- Lua plugin
- SVG plugin

CMakeLists.txt

@@ -0,0 +1,57 @@
+cmake_minimum_required(VERSION 3.16)
+project(rmlandroid LANGUAGES CXX)
+
+set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
+
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+
+find_package(PkgConfig REQUIRED)
+find_package(Freetype REQUIRED)
+find_package(SDL3 CONFIG REQUIRED)
+find_package(SDL3_image CONFIG REQUIRED)
+find_package(RmlUi CONFIG REQUIRED)
+
+add_library(rmlui_backend STATIC
+  vendor/rmlui_backend/RmlUi_Backend_SDL_SDLrenderer.cpp
+  vendor/rmlui_backend/RmlUi_Platform_SDL.cpp
+  vendor/rmlui_backend/RmlUi_Renderer_SDL.cpp
+)
+
+target_include_directories(rmlui_backend PUBLIC
+  vendor/rmlui_backend
+)
+
+target_compile_definitions(rmlui_backend PUBLIC
+  RMLUI_SDL_VERSION_MAJOR=3
+)
+
+target_link_libraries(rmlui_backend PUBLIC
+  RmlUi::RmlUi
+  SDL3::SDL3
+  SDL3_image::SDL3_image
+  Freetype::Freetype
+)
+
+add_executable(${PROJECT_NAME}
+  src/main.cpp
+)
+
+target_include_directories(${PROJECT_NAME} PRIVATE
+  src
+  ${FREETYPE_INCLUDE_DIRS}
+)
+
+target_link_libraries(${PROJECT_NAME} PRIVATE
+  rmlui_backend
+  RmlUi::RmlUi
+  RmlUi::Debugger
+  Freetype::Freetype
+)
+
+install(TARGETS ${PROJECT_NAME} DESTINATION bin)
+install(DIRECTORY assets DESTINATION bin)
+
+target_compile_definitions(${PROJECT_NAME} PRIVATE
+  ASSETS_DIR="${CMAKE_SOURCE_DIR}/bin/assets"
+)